100 DIMT$(4)
110 PRINT"[147]   DISK FILE LOG -BY JIM BUTTERFIELD"
115 PRINT"    64 MODIFICATION COPYRIGHT 1982"
116 PRINT"         BY JERRY BRINSON"
120 DATA 169,0,162,4,149,98,202,16,251,169,160,133,97,162,2,32,198,255
130 DATA 230,101,208,10,230,100,208,6,230,99,208,2,230,98,32,228,255,165,144
140 DATA 240,235,32,204,255,198,97,6,101,38,100,38,99,38,98,16,244,96
150 FORJ=860TO914:READX:POKEJ,X:NEXTJ
160 DATA "XXX","SEQ","PRG","USR","REL"
170 FORJ=0TO4:READT$(J):NEXT
180 INPUT"PRINTER";Z$
190 Z=3:IFASC(Z$)=89THENZ=4:INPUT"DATE[160][160]*[157][157][157]";D$
200 INPUT"FILE CHECK";Z$
210 IFASC(Z$)=89THENF=1
220 OPEN4,Z:OPEN1,8,15,"I0":CLOSE1
230 G$="                 "
240 OPEN1,8,3,"$0"
250 FORJ=1TO142:GET#1,A$:NEXTJ
260 FORJ=1TO16:GET#1,A$:IFA$=CHR$(160)GOTO280
270 N$=N$+A$
280 NEXTJ:GET#1,A$,A$
290 FORJ=1TO2:GET#1,A$:IFA$=CHR$(160)GOTO310
300 I$=I$+A$
310 NEXTJ
320 FORJ=1TO92:GET#1,A$:NEXTJ
330 PRINT#4,"*** DISK LOG ***  ";D$
340 PRINT#4,"DISK: ";N$;"   ID: ";I$
350 M=M+1:GET#1,K$,T$,S$:IFS$=""THENS$=CHR$(0)
360 F$="":FORJ=1TO16:GET#1,A$:IFA$=CHR$(160)GOTO380
370 F$=F$+A$
380 NEXTJ
390 FORJ=1TO10:GET#1,A$:NEXTJ
400 L=0:IFA$<>""THENL=ASC(A$)
410 GET#1,A$:IFM<8THENGET#1,A$,A$:GOTO430
420 M=0
430 SW=ST:IFK$=""GOTO640
440 K=ASC(K$)-128:IFK<1ORK>4THENK=0
450 IFZ=3ANDF=1GOTO480
460 H$=MID$(STR$(ASC(T$)),2):PRINT#4,LEFT$(G$,3-LEN(H$));H$;
470 H$=MID$(STR$(ASC(S$)),2):PRINT#4,LEFT$(G$,3-LEN(H$));H$;" ";
480 PRINT#4,T$(K);
490 H$=MID$(STR$(L),2):PRINT#4,LEFT$(G$,4-LEN(H$));H$;" ";
500 PRINT#4,F$;LEFT$(G$,17-LEN(F$));
510 IFK=0GOTO630
520 IFK=2ORF=1THENOPEN2,8,4,"0:"+F$+","+T$(K)+",R"
530 A=0:IFK<>2GOTO570
540 GET#2,A$,B$:A=0:IFA$<>""THENA=ASC(A$)
550 B=0:IFB$<>""THENB=ASC(B$)
560 GOSUB700
570 IFF=0GOTO620
580 POKE785,92:POKE786,3:A=A+USR(0)
590 IFK<>2THENPRINT#4,A;"BYTES";:GOTO620
600 PRINT#4," ";:A%=A/256:A=A-A%*256:B=B+A%
610 GOSUB700
620 CLOSE2
630 PRINT#4
640 IFSW=0GOTO350
650 CLOSE1:CLOSE4:END
700 X=B/16:GOSUB710:X=A/16
710 FORJ=1TO2:X%=X:X=(X-X%)*16:IFX%>9THENX%=X%+7
720 PRINT#4,CHR$(X%+48);:NEXTJ:RETURN